DTS COM O VISUAL STUDIO 2010 - SQLBULKCOPY

O Visual Studio 2010 incorporou diversas ferramentas práticas para que um desenvolvedor realize trabalhos variados sem muito esforço com várias ferramentas da Microsoft. A melhor delas talvez esteja relacionada com a utilização do SQL Server e a facilidade de se criar packages e DTS para se integralizar dados com o Bussines Intelligence (lembra do Visual Studio 2008?)

O SqlBulkcopy é uma ferramenta tipada que possibilita aos desenvolvedores criarem um tipo de DTS incorporado ao código-fonte de suas aplicações. Não é necessário ir até o SQL Server para que o DTS seja executado. Você pode abrir uma base de dados, zerá-la e copiar dados diretamente para outra base de dados sem problemas.

Um DTS trabalha internamente dentro do próprio SQL Server para copiar dados entre tabelas ou executar funcionalidades específicas como atualizar automaticamente dados seguindo determinados critérios estabelecidos. Geralmente utilizamos um DTS para copiar bases de dados de produção para uma base de testes ou para migrar informações necessárias em outros sistemas com outras bases de dados.



Para obter informações sobre a classe:


 http://msdn.microsoft.com/pt-br/library/system.data.sqlclient.sqlbulkcopy.aspx

Abaixo, o módulo-exemplo em VB.NET:

Module Module1
    Sub Main()       Dim connectionString As String = GetConnectionString()

        ' Open a connection to the AdventureWorks database.
        Using sourceConnection As SqlConnection = _
           New SqlConnection(connectionString)
            sourceConnection.Open()

            ' Perform an initial count on the destination table.
            Dim commandRowCount As New SqlCommand( _
            "SELECT COUNT(*) FROM dbo.BulkCopyDemoMatchingColumns;", _
                sourceConnection)
            Dim countStart As Long = _
               System.Convert.ToInt32(commandRowCount.ExecuteScalar())
            Console.WriteLine("Starting row count = {0}", countStart)

            ' Get data from the source table as a SqlDataReader.
            Dim commandSourceData As SqlCommand = New SqlCommand( _
               "SELECT ProductID, Name, ProductNumber " & _
               "FROM Production.Product;", sourceConnection)
            Dim reader As SqlDataReader = commandSourceData.ExecuteReader

            ' Open the destination connection. In the real world you would
            ' not use SqlBulkCopy to move data from one table to the other  
            ' in the same database. This is for demonstration purposes only.
            Using destinationConnection As SqlConnection = _
                New SqlConnection(connectionString)
                destinationConnection.Open()

                ' Set up the bulk copy object.
                ' The column positions in the source data reader
                ' match the column positions in the destination table,
                ' so there is no need to map columns.
                Using bulkCopy As SqlBulkCopy = _
                  New SqlBulkCopy(destinationConnection)
                    bulkCopy.DestinationTableName = _
                    "dbo.BulkCopyDemoMatchingColumns"

                    Try
                        ' Write from the source to the destination.
                        bulkCopy.WriteToServer(reader)

                    Catch ex As Exception
                        Console.WriteLine(ex.Message)

                    Finally
                        ' Close the SqlDataReader. The SqlBulkCopy
                        ' object is automatically closed at the end
                        ' of the Using block.
                        reader.Close()
                    End Try
                End Using

                ' Perform a final count on the destination table
                ' to see how many rows were added.
                Dim countEnd As Long = _
                    System.Convert.ToInt32(commandRowCount.ExecuteScalar())
                Console.WriteLine("Ending row count = {0}", countEnd)
                Console.WriteLine("{0} rows were added.", countEnd - countStart)

                Console.WriteLine("Press Enter to finish.")
                Console.ReadLine()
            End Using
        End Using
    End Sub

    Private Function GetConnectionString() As String
        ' To avoid storing the sourceConnection string in your code,
        ' you can retrieve it from a configuration file.
        Return "Data Source=(local);" & _
            "Integrated Security=true;" & _
            "Initial Catalog=AdventureWorks;"
    End Function
End Module
Veja que a função trabalha com duas conexões realizando a transferência de uma base de dados para outra. 

A facilidade apresentada pode ser realizada sem a criação de qualquer DTS nas base de dados de origem ou destino, simplesmente utilizando o Visual Studio 2010 para realizar este trabalho.

Reúna a coragem que lhe resta e atreva-se a fazer um DTS através de um código-fonte!


Sucesso a todos!